summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ec0a3b970515767a221fab6995a21a80af4a024f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
# Maintainer: Ian Brunelli (brunelli) <ianbrunelli@gmail.com>

pkgname=gnome-news-git
_gitname=gnome-news
pkgver=r240.775c743
pkgrel=1
pkgdesc='A GNOME 3 Feed Reader'
arch=('i686' 'x86_64')
license=('GPL3')
url="https://git.gnome.org/browse/${_gitname}"
depends=('gtk3' 'python' 'tracker>=1.5.1')
makedepends=('appstream-glib' 'autoconf' 'automake' 'git' 'intltool')
options=('!emptydirs')
install=gnome-news.install
source=("git://git.gnome.org/${_gitname}")
md5sums=('SKIP')
conflicts=('gnome-news')
provides=("gnome-news=$pkgver")

pkgver() {
	cd "${_gitname}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${_gitname}"
	./autogen.sh --prefix=/usr --disable-schemas-compile
	make
}

package() {
	cd "$srcdir/${_gitname}"
	make DESTDIR="${pkgdir}" install
}