blob: 28ffcc72bb3cbe15dfc6cd7412a05fc99adc84c5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=gnome-shell-extension-battery-health-charging-git
_uuid=Battery-Health-Charging@maniacx.github.com
pkgver=48.r5.g689bb0b
pkgrel=1
pkgdesc="An extension to maximize the battery life of laptops by setting their charging threshold/modes."
arch=('any')
url="https://github.com/maniacx/Battery-Health-Charging"
license=('GPL-3.0-or-later')
depends=('gnome-shell' 'polkit')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install=battery-health-charging.install
source=('git+https://github.com/maniacx/Battery-Health-Charging.git')
sha256sums=('SKIP')
pkgver() {
cd Battery-Health-Charging
git describe --long --tags | sed 's/^v0//;s/-GNOME45//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd Battery-Health-Charging
gnome-extensions pack ./ \
--extra-source=devices/ \
--extra-source=icons/ \
--extra-source=lib/ \
--extra-source=preferences/ \
--extra-source=resources/ \
--extra-source=tool/ \
--extra-source=ui/ \
--podir=po \
--force
}
package() {
cd Battery-Health-Charging
install -d "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}"
bsdtar xvf "${_uuid}.shell-extension.zip" -C \
"$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/" --no-same-owner
mv "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/locale" "$pkgdir/usr/share/"
install -Dm644 schemas/org.gnome.shell.extensions.Battery-Health-Charging.gschema.xml -t \
"$pkgdir/usr/share/glib-2.0/schemas/"
rm -rf "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/schemas"
}
|