blob: 1284f0696e79a90f91c4b9b689256f0aaa3ba84c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id$
# Maintainer: Mohammadreza Abdollahzadeh < morealaz at gmail dot com >
# Contributor: Carl George < arch at cgtx dot us >
pkgname=gnome-shell-extension-dash-to-panel-git
pkgver=46.r8.g79f54a6
pkgrel=1
pkgdesc='Extension for GNOME shell to combine the dash and main panel'
arch=(any)
_githubname=dash-to-panel
_githubowner=home-sweet-gnome
url="https://github.com/${_githubowner}/${_githubname}"
license=(GPL2)
depends=('gnome-shell>=3.22')
makedepends=('git' 'gnome-common' 'intltool')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
install='gnome-shell-extension.install'
source=("git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}/${_githubname}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${srcdir}/${_githubname}"
make _build
}
package() {
cd "${srcdir}/${_githubname}"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|