blob: 1d54becedfd3c6982998459ce8626f2d03a2e090 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Igor Dyatlov <dyatlov.igor@protonmail.com>
pkgname=gnome-shell-extension-hotkeys-popup-git
pkgver=4.r10.g0b11b5e
pkgrel=1
pkgdesc="GNOME Shell Extension that displays currently configured Gnome hotkeys in a popup."
arch=('any')
url="https://github.com/mipmip/gnome-shell-extensions-hotkeys-popup"
license=('GPL3')
depends=('gnome-shell')
makedepends=('git' 'zip')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=(${pkgname%-git}::git+$url.git)
b2sums=('SKIP')
pkgver() {
cd "${pkgname%-git}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "${pkgname%-git}"
./install.sh zip
}
package() {
_uuid='hotkeys-popup@pimsnel.com'
cd "${pkgname%-git}"
install -d "$pkgdir/usr/share/gnome-shell/extensions/$_uuid"
bsdtar -xvf $_uuid.zip -C "$pkgdir/usr/share/gnome-shell/extensions/$_uuid"
}
|