PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

# Maintainer: Kostas Kardaras <kostas.kardaras at gmail dot com>

pkgname=gnome-shell-extension-no-annoyance-2-git
pkgver=r58.9b992d9
pkgrel=1
pkgdesc='Another extension, that removes the Window is ready notification and puts the window into focus.'
url='https://github.com/jirkavrba/noannoyance'
license=('GPL2')
arch=('any')
conflicts=(${pkgname%-git})
provides=(${pkgname%-git})
makedepends=('git' 'zip')
depends=('gnome-shell>=45')
source=("${pkgname}::git+${url}.git")
sha512sums=('SKIP')

pkgver() {
  cd "$pkgname"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
  cd "$pkgname"
  uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
  destdir="$pkgdir/usr/share/gnome-shell/extensions/$uuid"
  install -dm755 "$destdir"
  install -dm755 "$destdir"/schemas
  install -Dm644 extension.js prefs.js metadata.json README.md LICENSE "$destdir"
  install -Dm644 schemas/* "$destdir"/schemas
}