PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Ricardo Liang <ricardoliang at gmail dot com>
pkgname=gnome-shell-extension-task-icons-git
pkgver=r23.0e3a429
pkgrel=1
pkgdesc='Adds task icons grouped by workspace to the panel.'
arch=('any')
url="https://github.com/rliang/gnome-shell-extension-task-icons"
license=('GPL3')
depends=('gnome-shell')
makedepends=('git')
optdepends=()
conflicts=('gnome-shell-extension-task-icons')
source=("${pkgname}::git+${url}.git")
md5sums=('SKIP')

pkgver() {
  cd "${pkgname}"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

package() {
  cd "${pkgname}"

  local _extname="$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)"

  install -Dm644 -t "${pkgdir}/usr/share/gnome-shell/extensions/${_extname}" *.js *.json gschemas.compiled
  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE
}