blob: 8c3ea2ee4e65bb857cc56164b4f81fdf4ab6a447 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Igor Dyatlov <dyatlov.igor@protonmail.com>
pkgname=gnome-shell-extension-wintile-git
_uuid=wintile@nowsci.com
pkgver=2026.05.26.r0.ga6b3cac
pkgrel=1
pkgdesc="Windows 10 window tiling for GNOME"
arch=('any')
url="https://nowsci.com/wintile"
license=('GPL-3.0-or-later')
depends=('gnome-shell')
makedepends=(
'git'
'jq'
'zip'
)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/fmstrat/wintile.git')
sha256sums=('SKIP')
pkgver() {
cd wintile
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-1//;s/-/./g'
}
build() {
cd wintile
sh bin/build.sh
}
package() {
cd wintile
_uuid=$(jq -r .uuid metadata.json)
install -d "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}"
bsdtar -xvf dist/G45/${_uuid}.zip -C \
"$pkgdir/usr/share/gnome-shell/extensions/${_uuid}" --no-same-owner
install -Dvm644 dist/G45/build/schemas/*.gschema.xml -t \
"$pkgdir/usr/share/glib-2.0/schemas/"
rm -rv "$pkgdir/usr/share/gnome-shell/extensions/${_uuid}/schemas/"
}
|