blob: c27ddcd260f625094dc59014ebeaff6bb72bdfe7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Stephan Springer <buzo+arch@Lini.de>
# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux@free.fr>
# Contributor: korjjj <korjjj+aur[at]gmail[dot]com>
pkgname=gns3-gui
pkgver=3.0.3
pkgrel=1
pkgdesc='GNS3 network simulator. Graphical user interface package.'
arch=(any)
url='https://github.com/GNS3/gns3-gui'
license=(GPL-3.0-only)
groups=(gns3)
depends=(
desktop-file-utils
python-distro
python-jsonschema
python-psutil
python-pyqt5
python-pyqt5-sip
python-sentry_sdk
python-truststore
qt5-svg
qt5-websockets
)
makedepends=(
python-build
python-installer
python-setuptools
)
optdepends=(
'gns3-server: GNS3 backend. Manages emulators such as Dynamips, VirtualBox or Qemu/KVM'
'xterm: Default terminal emulator for CLI management of virtual instances'
'wireshark-qt: Live packet capture')
source=("$pkgname-$pkgver.tar.gz::https://github.com/GNS3/$pkgname/archive/v$pkgver.tar.gz"
gns3.desktop
fix_requirements_for_Arch.diff)
sha256sums=('b10317821dc282634720b70a8b2a9970ca4d3036f5835e2db0e673166eff9cb7'
'51e6db5b47e6af3d008d85e8c597755369fafb75ddb2af9e79a441f943f4c166'
'41752bbc6658ba8658510371fada05ef90be7c61de774f38d941a306120c6f8a')
prepare() {
cd "$pkgname-$pkgver"
# Arch usually has the latest versions. Patch requirements to allow them.
patch --strip=2 -i "$srcdir"/fix_requirements_for_Arch.diff
}
build() {
cd "$pkgname-$pkgver"
python -m build --wheel --no-isolation
}
package() {
cd "$pkgname-$pkgver"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 "$srcdir"/gns3.desktop "$pkgdir"/usr/share/applications/gns3.desktop
install -Dm644 resources/images/gns3_icon_256x256.png "$pkgdir"/usr/share/pixmaps/gns3.png
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|