PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Tony Lambiris <tony@libpcap.net>

pkgname=go-kbdgrab
pkgver=r25.dce9421
pkgrel=1
pkgdesc='Key grabber written in golang for cleaning your keyboard'
arch=(i686 x86_64)
url='https://github.com/tonylambiris/go-kbdgrab'
license=(BSD)
makedepends=(go)
source=("git+https://github.com/tonylambiris/go-kbdgrab")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"

	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "${srcdir}/${pkgname}"

	install -m755 -d "${srcdir}/go/src/github.com/tonylambiris/"
	ln -sf "${srcdir}/${pkgname}" "${srcdir}/go/src/github.com/tonylambiris/go-kbdgrab"
}

build() {
	cd "${srcdir}/go/src/github.com/tonylambiris/go-kbdgrab"

	export GOPATH="${srcdir}/go"
	export PATH="${PATH}:${GOPATH}/bin"

	make
}

package() {
	cd "${srcdir}/go/src/github.com/tonylambiris/go-kbdgrab"

	install -m755 -D kbdgrab "${pkgdir}"/usr/bin/kbdgrab
}