blob: 015152021bd173e1bbd35e6b88457c695bacee35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
pkgbase=gobject-introspection-git
_pkgname=gobject-introspection
pkgname=(gobject-introspection-git gobject-introspection-runtime-git)
pkgver=1.64.0+75+g8b0a7f4c
pkgrel=1
pkgdesc="Introspection system for GObject-based libraries"
url="https://wiki.gnome.org/Projects/GObjectIntrospection"
arch=(x86_64)
license=(LGPL GPL)
depends=(python-mako python-markdown)
makedepends=(cairo git gtk-doc python-sphinx meson glib2)
provides=(gobject-introspection=$pkgver)
conflicts=(gobject-introspection)
options=(!emptydirs)
source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git"
"git+https://gitlab.gnome.org/GNOME/glib.git")
sha512sums=('SKIP'
'SKIP')
validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip@tecnocode.co.uk>
pkgver() {
cd $_pkgname
git describe --tags | sed 's/-/+/g'
}
build() {
arch-meson $_pkgname build \
-D gtk_doc=true \
-D glib_src_dir="$srcdir/glib"
ninja -C build
}
check() {
meson test -C build
}
package_gobject-introspection-git() {
depends+=("gobject-introspection-runtime")
DESTDIR="$pkgdir" meson install -C build
python -m compileall -d /usr/lib/$_pkgname "$pkgdir/usr/lib/$_pkgname"
python -O -m compileall -d /usr/lib/$_pkgname "$pkgdir/usr/lib/$_pkgname"
### Split runtime
mkdir -p "$srcdir/runtime/lib"
mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
}
package_gobject-introspection-runtime-git() {
pkgdesc+=" (runtime library)"
depends=(glib2)
provides=(gobject-introspection-runtime=$pkgver libgirepository-1.0.so)
conflicts=(gobject-introspection-runtime)
mv "$srcdir/runtime" "$pkgdir/usr"
}
|