PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 2018 Google Inc. All Rights Reserved.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

# Maintainer: Lorenzo Castelli <lcastelli@google.com>
# Maintainer: Samuel Littley <samuellittley@google.com>

pkgname='google-compute-engine-oslogin'
pkgver=20231004.00
pkgrel=1
pkgdesc='OS Login Guest Environment for Google Compute Engine'
arch=('x86_64')
url='https://github.com/GoogleCloudPlatform/guest-oslogin'
license=('Apache')
depends=('curl' 'json-c' 'pam')
checkdepends=('gtest')
source=("$pkgname-$pkgver.tar.gz::https://github.com/GoogleCloudPlatform/guest-oslogin/archive/$pkgver.tar.gz"
        'google-compute-engine-oslogin.install')
sha256sums=('d44f85167fd9281129547f279e767e40f4104328998202a52d92b422f23b104a'
            '3e488f66f6ddc5882d731bd951391efe588c1fbb19afcf4de5283ec7fd481039')
install='google-compute-engine-oslogin.install'

build() {
	cd "guest-oslogin-$pkgver"
	make
}

check() {
	cd "guest-oslogin-$pkgver"
	make GTEST_DIR=/usr/src/googletest non_network_tests
}

package() {
	cd "guest-oslogin-$pkgver"
	make VERSION="$pkgver" DESTDIR="$pkgdir/" SYSTEMDDIR=/usr/lib/systemd/system \
		PRESETDIR=/usr/lib/systemd/system-preset install
}