blob: f72ec0ade87d9f1b2269d33ccc46baf8226b65d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Adam Perkowski <adas1per@protonmail.com>
# https://github.com/adamperkowski/PKGBUILDs
pkgname=goskyr
pkgver=0.5.43
pkgrel=1
pkgdesc='Configurable command-line web scraper'
arch=('x86_64')
url="https://github.com/jakopako/$pkgname"
license=('GPL-3.0-or-later')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('2c3d6a56333d5d7bc99aecc409f9c222d98cf3c08f2e4b57cbf186d71022b5a9')
makedepends=('go')
depends=('glibc')
prepare() {
cd "$pkgname-$pkgver"
mkdir -p build
}
build() {
cd "$pkgname-$pkgver"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export CGO_LDFLAGS="$LDFLAGS"
export GOPATH="$srcdir"
export GOFLAGS='-buildmode=pie -mod=readonly -modcacherw'
go build -o "build/$pkgname" .
}
check() {
cd "$pkgname-$pkgver"
go test .
}
package() {
cd "$pkgname-$pkgver"
install -Dm0755 "build/$pkgname" -t "$pkgdir/usr/bin"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
}
# vim: ts=2 sw=2 et:
|