PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: Marcin (CTRL) Wieczorek <marcin@marcin.co>
# Contributor: Yamashita Ren
# Contributor: Ner0

pkgname=gpaste-daemon
pkgver=3.24.1
pkgrel=1
pkgdesc="A clipboard management daemon"
arch=('i686' 'x86_64')
url="http://www.imagination-land.org/tags/GPaste.html"
license=('GPL3')
depends=('systemd' 'xcb-util-keysyms' 'appstream-glib')
makedepends=('gobject-introspection' 'intltool')
conflicts=('cinnamon-extension-gpaste' 'gpaste')
provides=('gpaste')
options=('!emptydirs' '!libtool')
install=$pkgname.install
source=("http://www.imagination-land.org/files/gpaste/gpaste-$pkgver.tar.xz")
sha256sums=('0238252a8e2ad92ffb0dd797952dd28086901cdfe9d4010a07c33401403351e3')

build () {
    cd ${pkgname%-*}-${pkgver}

    ./configure --prefix=/usr --sysconfdir=/etc --libexecdir=/usr/lib --disable-applet --disable-gnome-shell-extension --without-controlcenterdir --disable-schemas-compile --disable-vala
    make
}

package () {
    cd ${pkgname%-*}-${pkgver}
    make DESTDIR="$pkgdir/" install

    install -Dpm644 data/completions/gpaste-client "$pkgdir/etc/bash_completion.d/gpaste-client"
    install -Dpm644 data/completions/_gpaste-client "$pkgdir/usr/share/zsh/site-functions/_gpaste-client"
    rm -rf "$pkgdir/no"
}