summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 765f9d6034b1cdff379927e4c78e753e4f7d5f5c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
# -*- mode: sh -*-

# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>

pkgname='gpp-git'
_pkgname="${pkgname/-git/}"
pkgver=2.28.r0.gfc9cc00
pkgrel=3
pkgdesc='General-purpose preprocessor with customizable syntax (development version)'
arch=('aarch64' 'armv7h' 'i686' 'x86_64')
url='https://github.com/logological/gpp'
source=("git+$url.git")
license=(
  'GPL-3.0-or-later'   # SPDX-License-Identifier: GPL-3.0-or-later
  'LGPL-3.0-or-later'  # SPDX-License-Identifier: LGPL-3.0-or-later
)
provides=("$_pkgname")
conflicts=("${provides[@]}")
depends=('glibc')
makedepends=('git')
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgname"

  git describe --tags --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$_pkgname"

  aclocal \
  && autoheader \
  && automake --add-missing \
  && autoconf \
  && ./configure \
       --prefix='/usr' \
       --docdir="/usr/share/doc/$pkgname" \
       --mandir='/usr/share/man'

  make
}

check() {
  cd "$_pkgname"

  src/gpp --version
}

package() {
  cd "$_pkgname"

  make DESTDIR="$pkgdir" install

  rm -vf "$pkgdir/usr/share/doc/$pkgname/gpp.1"

  install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname" \
    AUTHORS NEWS README.md THANKS
}

# eof