PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer:

_pkgname="gpu-screen-recorder-gtk"
pkgname="$_pkgname-git"
pkgver=5.7.7.r0.g32b9725
pkgrel=1
pkgdesc="Frontend for gpu-screen-recorder, a shadowplay-like screen recorder"
url="https://git.dec05eba.com/gpu-screen-recorder-gtk"
license=('GPL-3.0-only')
arch=('x86_64')

depends=(
  'gtk3'
  'libayatana-appindicator'
  'libx11'
)
makedepends=(
  'desktop-file-utils'
  'git'
  'gtk-update-icon-cache'
  'meson'
)

provides=("$_pkgname")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$(sed 's&//git\.&//repo.&' <<< "$url")")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  arch-meson "$_pkgsrc" build
  meson compile -C build
}

check() {
  meson test -C build
}

package() {
  depends+=(
    'gpu-screen-recorder' # AUR
  )
  meson install -C build --destdir "$pkgdir"
}