PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer:
# Contributor: Martyn van Dijke <martijn_vdijke at hotmail dot com>

: ${_version_gnuradio:=3.10}

_pkgname="gr-lora_sdr"
pkgname="$_pkgname-git"
pkgver=0.5.r4.g8133965
pkgrel=2
pkgdesc="GNU Radio blocks for fully-functional LoRa transceiver"
url="https://github.com/martynvdijke/gr-lora_sdr"
license=('GPL-3.0-or-later')
arch=('x86_64')

depends=(
  "gnuradio>=$_version_gnuradio"
  'python'
)
makedepends=(
  'boost'
  'cmake'
  'git'
  'ninja'
  'pybind11'
)

provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")

_pkgsrc="$_pkgname"
source=("$_pkgsrc"::"git+$url.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_pkgsrc"
  git describe --long --tags --abbrev=7 \
    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  local _cmake_options=(
    -B build
    -S "$_pkgsrc"
    -G Ninja
    -DCMAKE_BUILD_TYPE=None
    -DCMAKE_INSTALL_PREFIX='/usr'
    -Wno-dev
  )

  cmake "${_cmake_options[@]}"
  cmake --build build
}

package() {
  depends+=(
    'python-loudify' # AUR
    'python-pandas'
  )

  DESTDIR="$pkgdir" cmake --install build
}