blob: a96859ba916edc8ac18a6411273d72c2347ea881 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Lucas Werkmeister <mail@lucaswerkmeister.de>
java_=11
pkgname_=graaljs
pkgname="${pkgname_}-jdk${java_}-bin"
pkgver=22.3.2
pkgrel=1
pkgdesc="GraalVM-based, polyglot-enabled implementation of JavaScript, Java ${java_} version"
arch=('x86_64'
'aarch64')
url='https://github.com/oracle/graaljs'
license=('custom')
depends=("jdk${java_}-graalvm-bin")
source_x86_64=("https://github.com/oracle/$pkgname_/releases/download/vm-${pkgver}/js-installable-svm-java${java_}-linux-amd64-${pkgver}.jar")
source_aarch64=("https://github.com/oracle/$pkgname_/releases/download/vm-${pkgver}/js-installable-svm-java${java_}-linux-aarch64-${pkgver}.jar")
sha256sums_x86_64=('1febca4c31aacae772d09d911598ffd58a6afd3dce6dec78fd37e8b3468d4ce2')
sha256sums_aarch64=('481c91584fb03666e8402167f7c45bbdcf724d822ce82b2d0a141a4ee0e01c8c')
package() {
local file eq permissions mode name target
mkdir -p "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/"
cp -a -t "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/" languages/ lib/ LICENSE_GRAALJS.txt THIRD_PARTY_LICENSE_GRAALJS.txt
printf '\n' >> META-INF/permissions
while read -r file eq permissions; do
if [[ $eq != '=' ]]; then
printf >&2 'second word should be "=": %s %s %s\n' "$file" "$eq" "$permissions"
return 1
fi
case $permissions in
'rw-------') mode=600;;
'rw-r--r--') mode=644;;
'rw-rw-r--') mode=664;;
'rwxr-xr-x') mode=755;;
'rwxrwxr-x') mode=775;;
'rwxrwxrwx') continue;; # symbolic link
*)
printf >&2 'unknown permissions: %s\n' "$permissions"
return 1
;;
esac
chmod "$mode" -- "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/$file"
done < META-INF/permissions
printf '\n' >> META-INF/symlinks
while read -r name eq target; do
if [[ $eq != '=' ]]; then
printf >&2 'second word should be "=": %s %s %s\n' "$name" "$eq" "$target"
return 1
fi
mkdir -p -- "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/$(dirname -- "$name")"
ln -s -- "$target" "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/$name"
done < META-INF/symlinks
# already in jdk${java_}-graalvm-bin package
unlink "$pkgdir/usr/lib/jvm/java-${java_}-graalvm/lib/installer/components/org.graalvm.component"
install -DTm644 LICENSE_GRAALJS.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|