PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Piroro-hs

pkgname=gsettings-desktop-schemas-nofont
pkgver=44.0
pkgrel=1
pkgdesc='Shared GSettings schemas for the desktop, patched to drop font dependencies'
arch=('any')
url="https://gitlab.gnome.org/GNOME/${pkgname%-nofont}"
license=('GPL')
groups=()
depends=('dconf' 'glib2')
makedepends=('git' 'gobject-introspection' 'meson')
provides=("${pkgname%-nofont}")
conflicts=("${pkgname%-nofont}")
replaces=()
backup=()
options=()
install=
source=("$pkgname::git+$url.git#tag=$pkgver"
        "0001-Revert-default-font.patch")
noextract=()
sha256sums=('SKIP'
            '70823e18b0b35f698890cee555afee794e805750e798e0c76a1f0d456aaf587d')

prepare() {
	cd "$srcdir/$pkgname"
	patch -p1 -i "../0001-Revert-default-font.patch"
}

build() {
	arch-meson "$pkgname" build
	meson compile -C build
}

check() {
	meson test -C build --print-errorlogs
}

package() {
	meson install -C build --destdir "$pkgdir"
}