blob: f69becadf739927c41e675b9f9032e35d4324daa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Mantas Mikulėnas <grawity@gmail.com>
pkgname=gss-ntlmssp
pkgver=1.3.1
pkgrel=1
pkgdesc="A GSSAPI Mechanism that implements NTLMSSP"
url="https://github.com/gssapi/gss-ntlmssp"
arch=(i686 x86_64)
license=(custom:ISC)
depends=(krb5 libunistring libwbclient openssl)
makedepends=(docbook-xsl doxygen git)
_commit=3a24e4579c4187f6aadff1243610890c9e6d690e
source=("git+https://github.com/gssapi/gss-ntlmssp.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd $pkgname
git describe --tags | sed "s/^v//; s/-/.r/; s/-/./"
}
prepare() {
cd $pkgname
autoreconf -fi
}
build() {
cd $pkgname
./configure --prefix=/usr
make
# Krb5 plugin config
sed -i 's,\${exec_prefix},/usr,g' examples/mech.ntlmssp
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
# Krb5 plugin config
install -Dm644 examples/mech.ntlmssp "$pkgdir/etc/gss/mech.d/gssntlmssp.conf"
# License
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim: ts=2:sw=2:et
|