summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: ac77756874f9f6b1db2de38766d0256992f18413 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
pkgname=('palenight-gtk-theme' 'amarena-gtk-theme' 'gruvterial-gtk-theme')
pkgbase=gtk-theme-framework
pkgver=0.2.1
pkgrel=1
pkgdesc="GTK themes built with the GTK Theme Framework"
arch=('any')
url="https://github.com/jaxwilko/gtk-theme-framework"
license=('GPL3')
depends=('gtk3' 'gtk-engine-murrine' 'gtk-engines')
makedepends=('sassc' 'inkscape' 'optipng')
conflicts=('material-gtk-framework')
replaces=('material-gtk-framework')
options=('!strip')
source=("$pkgbase-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
        'git+https://github.com/vinceliuice/vimix-icon-theme.git')
sha256sums=('90fdab6c78b8cbb262cc9b99125a156bcdda1133f8d69a71d94b7ca6baae9fe9'
            'SKIP')

prepare() {
	cd "$pkgbase-$pkgver"
	if [[ ! -d src/icons/vimix-icon-theme ]]; then
		ln -s "$srcdir/vimix-icon-theme" src/icons/vimix-icon-theme
	fi
}

build() {
	cd "$pkgbase-$pkgver"

	# Remove precompiled assets
	rm -rf dist

	./main.sh -vcf
	./main.sh -t amarena -vcf
	./main.sh -t gruvterial -vcf
}

package_palenight-gtk-theme() {
	cd "$pkgbase-$pkgver"
	install -d "$pkgdir"/usr/share/{icons,themes}
	./main.sh -v -id "$pkgdir/usr/share/themes" \
		-op "$pkgdir/usr/share/icons"
}

package_amarena-gtk-theme() {
	cd "$pkgbase-$pkgver"
	install -d "$pkgdir"/usr/share/{icons,themes}
	./main.sh -t amarena -v -id "$pkgdir/usr/share/themes" \
		-op "$pkgdir/usr/share/icons"
}

package_gruvterial-gtk-theme() {
	cd "$pkgbase-$pkgver"
	install -d "$pkgdir"/usr/share/{icons,themes}
	./main.sh -t gruvterial -v -id "$pkgdir/usr/share/themes" \
		-op "$pkgdir/usr/share/icons"
}