summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8dd64b0ec8f5bee13ce6c64f1aee1ff5be1bedf2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# Maintainer: Paco Pascal <me@pacopascal.com>

_pkgname='guile-zlib'
pkgname="${_pkgname}-git"
pkgver=r17.429b3c6
pkgrel=1
pkgdesc='Guile-zlib is a GNU Guile library providing bindings to zlib.'
arch=('x86_64')
url='https://notabug.org/guile-zlib/guile-zlib'
license=('GPL3')
options=('!strip')
depends=('guile' 'zlib')
makedepends=('git')
conflicts=("${pkgname%-git}")
provides=("${pkgname%-git}")
source=('git+https://notabug.org/guile-zlib/guile-zlib.git')
md5sums=('SKIP')

pkgver() {
    # Number of revisions since beginning of the history.
    cd "${_pkgname}"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

prepare() {
    cd "${_pkgname}"
    aclocal
    autoconf
    automake --add-missing
}

build() {
    cd "${_pkgname}"
    ./configure --prefix=/usr
    make
}

check() {
    cd "${_pkgname}"
    make check
}

package() {
    cd "${_pkgname}"
    make DESTDIR="$pkgdir/" install
}