blob: 9a533f78750de12bf7527541666a8763dc61bf99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
|
# Maintainer: Holger Obermaier <holgerob@gmx.de>
# Contributor: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sebastien Piccand <sebcactus gmail com>
pkgname=(
'handbrake-llvm-optimized'
'handbrake-llvm-optimized-cli'
)
# Follow handbrakes most current stable branch 1.8.x
# https://github.com/HandBrake/HandBrake/commits/1.8.x
readonly _commit=1b09b55fa971682658f9ad22e9d4acbc21dc4a33
pkgver() {
git -C HandBrake/ gc --auto --prune=now
git -C HandBrake/ describe ${_commit} | sed -e 's/^v//g' -e 's/-/.r/' -e 's/-/./'
}
pkgver=1.8.2.r2.g1b09b55fa
pkgrel=2
arch=('x86_64')
url="https://handbrake.fr/"
license=('GPL')
_commondeps=(
'bzip2'
'fribidi'
'gcc-libs'
'jansson'
'lame'
'libass'
'libjpeg-turbo'
'libogg'
'libtheora'
'libva'
'libvorbis'
'libvpx'
'libxml2'
'numactl'
'opus'
'speex'
'x264'
'xz'
'zlib'
)
_guideps=(
'at-spi2-core'
'cairo'
'fontconfig'
'freetype2'
'gdk-pixbuf2'
'glib2'
'gst-plugins-base'
'gst-plugins-base-libs'
'gstreamer'
'gtk4'
'harfbuzz'
'libgudev'
'pango'
)
makedepends=(
'base-devel'
'intltool'
'python'
'nasm'
'wget'
'cmake'
'meson'
'git'
'clang'
'lld'
'llvm'
# AMD VCE encoding on Linux requires Vulkan
'vulkan-headers'
"${_commondeps[@]}"
"${_guideps[@]}"
)
options=('!lto') # https://bugs.archlinux.org/task/72600
source=("HandBrake::git+https://github.com/HandBrake/HandBrake.git#tag=${_commit}")
sha256sums=('SKIP')
prepare() {
patch --directory=HandBrake --strip 1 <<-'EOF'
--- a/contrib/svt-av1/module.defs
+++ b/contrib/svt-av1/module.defs
@@ -1,9 +1,9 @@
$(eval $(call import.MODULE.defs,SVT-AV1,svt-av1))
$(eval $(call import.CONTRIB.defs,SVT-AV1))
-SVT-AV1.FETCH.url = https://github.com/HandBrake/HandBrake-contribs/releases/download/contribs/SVT-AV1-v2.1.0.tar.gz
-SVT-AV1.FETCH.url += https://gitlab.com/AOMediaCodec/SVT-AV1/-/archive/v2.1.0/SVT-AV1-v2.1.0.tar.gz
-SVT-AV1.FETCH.sha256 = 72a076807544f3b269518ab11656f77358284da7782cece497781ab64ed4cb8a
+SVT-AV1.FETCH.url = https://github.com/HandBrake/HandBrake-contribs/releases/download/contribs/SVT-AV1-v2.3.0.tar.gz
+SVT-AV1.FETCH.url += https://gitlab.com/AOMediaCodec/SVT-AV1/-/archive/v2.3.0/SVT-AV1-v2.3.0.tar.gz
+SVT-AV1.FETCH.sha256 = ebb0b484ef4a0dc281e94342a9f73ad458496f5d3457eca7465bec943910c6c3
SVT-AV1.GCC.args.c_std =
EOF
}
setup_compiler() {
export CC="/usr/bin/clang"
unset CFLAGS
export CXX="/usr/bin/clang++"
unset CXXFLAGS
export CPP="/usr/bin/clang-cpp"
export LD="/usr/bin/lld"
export LDFLAGS="-fuse-ld=lld"
export AR="/usr/bin/llvm-ar"
export RANLIB="/usr/bin/llvm-ranlib"
export NM="/usr/bin/llvm-nm"
export ADDR2LINE="/usr/bin/llvm-addr2line"
export OBJCOPY="/usr/bin/llvm-objcopy"
export OBJDUMP="/usr/bin/llvm-objdump"
export READELF="/usr/bin/llvm-readelf"
export STRIP="/usr/bin/llvm-strip"
}
build() {
setup_compiler
local -a CONFIGURE_OPTIONS=(
--launch-jobs=0
--prefix=/usr
--cc="${CC}"
--ar="${AR}"
--ranlib="${RANLIB}"
--strip="${STRIP}"
--optimize=speed
--cpu=native
--lto=on
--enable-qsv
--enable-vce
)
cd "${srcdir}/HandBrake" || exit
./configure "${CONFIGURE_OPTIONS[@]}"
make -C build
}
package_handbrake-llvm-optimized() {
pkgdesc="Multithreaded video transcoder optimized with LLVM"
depends=(
'desktop-file-utils'
'hicolor-icon-theme'
"${_commondeps[@]}"
"${_guideps[@]}"
)
optdepends=(
'gst-plugins-good: for video previews'
'gst-libav: for video previews'
'intel-media-sdk: Intel QuickSync support'
'libdvdcss: for decoding encrypted DVDs'
)
provides=(handbrake)
conflicts=(handbrake)
make \
--directory="${srcdir}/HandBrake/build" \
DESTDIR="${pkgdir}" \
install
rm "${pkgdir}/usr/bin/HandBrakeCLI"
}
package_handbrake-llvm-optimized-cli() {
pkgdesc="Multithreaded video transcoder optimized with LLVM (CLI)"
depends=("${_commondeps[@]}")
optdepends=(
'intel-media-sdk: Intel QuickSync support'
'libdvdcss: for decoding encrypted DVDs'
)
provides=(handbrake-cli)
conflicts=(handbrake-cli)
install -D "${srcdir}/HandBrake/build/HandBrakeCLI" "${pkgdir}/usr/bin/HandBrakeCLI"
}
|