blob: 9db1aba4e14f4b021aea6eae1f64fb0d2ab9b6f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Chih-Hsuan Yen <yan12125@gmail.com>
# Forked from heimdall-git; original contributors:
# Contributor: Todd Musall
# Contributor: dront78 (Ivan)
# Contributor: Victor Noel
# Contributor: Lari Tikkanen
pkgname=heimdall-nogui-git
_pkgname="heimdall"
pkgver=1.4.2.r7.ga2cfdaa
pkgrel=2
pkgdesc="A cross-platform open-source utility to flash firmware (aka ROMs) onto Samsung Galaxy S devices."
arch=('i686' 'x86_64')
url="https://glassechidna.com.au/heimdall/"
license=('MIT')
depends=('libusb')
makedepends=('cmake' 'git')
optdepends=('android-udev: Udev rules to connect Android devices to you linux box')
conflicts=("$_pkgname")
provides=("$_pkgname=$pkgver")
source=("$_pkgname::git+https://gitlab.com/BenjaminDobell/Heimdall.git"
"BridgeManager.patch")
md5sums=('SKIP'
'8fce869eb9539b6b410b1a52370c3824')
pkgver() {
cd $_pkgname
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd $_pkgname
patch -Np1 -i ../BridgeManager.patch
mkdir -p build
}
build() {
cd $_pkgname/build
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DDISABLE_FRONTEND=ON \
..
make
}
package() {
cd $_pkgname/build
make DESTDIR="$pkgdir" install
install -m644 -D ../LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|