blob: 673e7c8bfed0073a1829305732a0cf09a1566853 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
pkgname=heroic-games-launcher
pkgver=2.14.1
pkgrel=1
pkgdesc="Native GOG, Epic Games and Amazon games launcher for Linux"
arch=(x86_64)
url="https://heroicgameslauncher.com/"
license=(GPL3)
depends=(alsa-lib gtk3 nss )
makedepends=(git yarn node-gyp)
options=(!debug)
source=("git+https://github.com/Heroic-Games-Launcher/HeroicGamesLauncher.git#tag=v${pkgver}")
sha256sums=('SKIP')
build() {
cd HeroicGamesLauncher
yarn
yarn dist:linux tar.xz
}
package() {
cd HeroicGamesLauncher
install -d "${pkgdir}/opt/heroic"
cp -r dist/linux-unpacked/* "${pkgdir}/opt/heroic"
install -d "${pkgdir}/usr/bin"
ln -s /opt/heroic/heroic "${pkgdir}/usr/bin/heroic"
install -D public/icon.png "${pkgdir}/usr/share/pixmaps/heroic.png"
install -d "${pkgdir}/usr/share/applications/"
cat > ${pkgdir}/usr/share/applications/heroic.desktop << _EOD
[Desktop Entry]
Name=Heroic Games Launcher
Exec=/opt/heroic/heroic %U
Terminal=false
Type=Application
Icon=heroic
StartupWMClass=Heroic
Comment=Open Source GOG and Epic Games launcher
MimeType=x-scheme-handler/heroic;
Categories=Game;
_EOD
}
|