blob: e4060866af5e6cbad2748eab57d9d0e5e0940d25 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Duncan Deveaux <duncan.at.hikounomizu.dot.org>
pkgname=hikounomizu
pkgver=1.0.1
pkgrel=1
pkgdesc="Platform-based, anime-styled fighting game"
arch=('x86_64')
url="https://hikounomizu.org"
license=('custom')
depends=('sdl2' 'sdl2_image' 'libgl' 'freetype2' 'openal' 'libvorbis' 'enet' 'pugixml')
makedepends=('cmake>=3.13' 'gendesk')
source=("https://download.tuxfamily.org/hnm/1.0.1/hikounomizu-1.0.1-src-withdata.tar.bz2")
md5sums=('d1f06d25c7baac59f5a0615e8fa9fb63')
prepare() {
gendesk -n -f --pkgname "${pkgname}" --pkgdesc "${pkgdesc}" \
--name 'Hikou no mizu' --categories 'Game;ArcadeGame'
}
build() {
cmake -B build -S "${pkgname}-${pkgver}" \
-DCMAKE_BUILD_TYPE='None' \
-DCMAKE_INSTALL_PREFIX='/usr' \
-Wno-dev
make -C build
}
package() {
# Install License & README
install -Dm644 "${pkgname}-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
install -Dm644 "${pkgname}-${pkgver}/datasrc/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/DATA_COPYING"
install -Dm644 "${pkgname}-${pkgver}/GPL" "${pkgdir}/usr/share/licenses/${pkgname}/GPL"
install -Dm644 "${pkgname}-${pkgver}/README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
install -Dm644 "${pkgname}-${pkgver}/CHANGES.md" "${pkgdir}/usr/share/doc/${pkgname}/CHANGES.md"
# Install Desktop & Icon files
install -Dm644 "${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
install -Dm644 "${pkgname}-${pkgver}/data/gfx/icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
# Install data & binary
make -C build DESTDIR="${pkgdir}" install
}
|