blob: d9ef3b621f099effaf9ad9677c968b5f423d69c0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Torsten Keßler <tpkessler at archlinux dot org>
# Contributor: Markus Näther <naetherm@informatik.uni-freiburg.de>
# Contributor: acxz <akashpatel2008 at yahoo dot com>
pkgname=hipsparse
pkgver=5.4.1
pkgrel=1
pkgdesc='rocSPARSE marshalling library.'
arch=('x86_64')
url='https://hipsparse.readthedocs.io/en/latest/'
license=('MIT')
depends=('hip' 'rocsparse')
makedepends=('rocm-cmake' 'gcc-fortran')
_git='https://github.com/ROCmSoftwarePlatform/hipSPARSE'
source=("$pkgname-$pkgver.tar.gz::$_git/archive/rocm-$pkgver.tar.gz"
"hipsparse-no-git.patch::$_git/commit/23704c1257747f325a1f3db4e9c35f2d6ba724ad.patch")
sha256sums=('fdc9b7f6ce27b544c4be102ca25967ff61272111acdd52d6e21eeeace0213792'
'0f4ca37b246e9908ebb3a80818abb28b4c6996036b65f8f89be9affc854efa7f')
_dirname="$(basename "$_git")-$(basename "${source[0]}" ".tar.gz")"
prepare() {
cd "$_dirname"
patch -Np1 -i "$srcdir/hipsparse-no-git.patch"
}
build() {
# -fcf-protection is not supported by HIP, see
# https://docs.amd.com/bundle/ROCm-Compiler-Reference-Guide-v5.4/page/Appendix_A.html
CXXFLAGS="${CXXFLAGS} -fcf-protection=none" \
HIP_PATH=/opt/rocm \
cmake \
-Wno-dev \
-B build \
-S "$_dirname" \
-DCMAKE_BUILD_TYPE=None \
-DCMAKE_CXX_COMPILER=/opt/rocm/bin/hipcc \
-DCMAKE_INSTALL_PREFIX=/opt/rocm
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
echo "/opt/rocm/$pkgname/lib" > "$pkgname.conf"
install -Dm644 "$pkgname.conf" "$pkgdir/etc/ld.so.conf.d/$pkgname.conf"
install -Dm644 "$srcdir/$_dirname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|