blob: 428f4fae7822986bcbebf6e624afb3eb9e5dcdf8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Guilhem Saurel <saurel@laas.fr>
_org='humanoid-path-planner'
_pkgname='hpp-fcl'
pkgname=("$_pkgname" "$_pkgname-docs")
pkgver=2.4.4
pkgrel=1
pkgdesc="An extension of the Flexible Collision Library"
arch=('i686' 'x86_64')
url="https://github.com/$_org/$_pkgname"
license=('BSD-2-Clause')
depends=('assimp' 'eigen' 'eigenpy' 'octomap' 'qhull' 'python-numpy' 'boost-libs' 'python' 'glibc' 'gcc-libs')
optdepends=('doxygen')
makedepends=('cmake' 'boost')
source=("$url/releases/download/v$pkgver/$_pkgname-$pkgver.tar.gz"{,.sig})
sha256sums=('cae32b6beb6a93896bf566453e6897606763219cebb3dbfaa229a1e4214b542a'
'SKIP')
validpgpkeys=(
'9B1A79065D2F2B806C8A5A1C7D2ACDAF4653CF28' # https://github.com/nim65s.gpg
'A031AD35058955293D54DECEC45D22EF408328AD' # https://github.com/jcarpent.gpg
'F534E75540B2E7D24F99746987CFFF3D0D73CC93' # https://github.com/jcarpent.gpg
'1462AF00C9CF3C9E7AFC905E63380359F089A579' # https://github.com/jorisv.gpg
)
build() {
cmake -B "build-$pkgver" -S "$pkgbase-$pkgver" \
-DHPP_FCL_HAS_QHULL=ON \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_INSTALL_PREFIX=/usr \
-DGENERATE_PYTHON_STUBS=ON \
-DINSTALL_DOCUMENTATION=ON \
-DBUILD_DOCUMENTATION=ON \
-Wno-dev
cmake --build "build-$pkgver"
}
check() {
cmake --build "build-$pkgver" -t test
}
package_hpp-fcl() {
DESTDIR="$pkgdir/" cmake --build "build-$pkgver" -t install
rm -rf "$pkgdir/usr/share/doc"
sed -i 's=;/usr/\.\./include/include==' "$pkgdir/usr/lib/cmake/hpp-fcl/hpp-fclTargets.cmake"
sed -i '/Boost COMPONENTS/s/python3//' "$pkgdir/usr/lib/cmake/hpp-fcl/hpp-fclConfig.cmake"
install -Dm644 "$pkgbase-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_hpp-fcl-docs() {
DESTDIR="$pkgdir/" cmake --build "build-$pkgver" -t install
rm -rf "$pkgdir"/usr/{lib,include,share/{"$_pkgname",ament_index}}
install -Dm644 "$pkgbase-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|