blob: 104d252d3ba4fdd9fe1c38b457018468e8f281c3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Dawid Potocki <archlinux a dawidpotocki , com>
_pkgname=htop
pkgname="${_pkgname}-vim"
pkgver=3.3.0
pkgrel=1
pkgdesc='Interactive process viewer with a Vim keybindings patch'
arch=('x86_64')
url='https://htop.dev/'
license=('GPL')
depends=('libcap' 'libcap.so' 'libnl' 'ncurses' 'libncursesw.so')
makedepends=('lm_sensors')
optdepends=('lm_sensors: show cpu temperatures'
'lsof: show files opened by a process'
'strace: attach to a running process')
provides=('htop')
conflicts=('htop')
options=('!emptydirs')
source=("https://github.com/htop-dev/htop/archive/${pkgver}/${_pkgname}-${pkgver}.tar.gz"
'vim-keybindings.patch'
)
sha256sums=('1e5cc328eee2bd1acff89f860e3179ea24b85df3ac483433f92a29977b14b045'
'f1b8caac69f8021b5abe31de562836930cd4ac856a28d3809697016844d2a592')
prepare() {
cd "${_pkgname}-${pkgver}"
patch -Np1 < ../vim-keybindings.patch
autoreconf -fi
}
build() {
cd "${_pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-cgroup \
--enable-delayacct \
--enable-openvz \
--enable-unicode \
--enable-vserver
make
}
package() {
make -C "${_pkgname}-${pkgver}" DESTDIR="${pkgdir}" install
}
|