blob: a72a096f8d0d8e71899860692c181deb13efef7d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Dimitris Kiziridis <ragouel at outlook dot com>
# Contributor: Jean Lucas <jean@4ray.co>
pkgname=hunter-git
pkgver=1.3.5.r85.g17946cf
pkgrel=1
pkgdesc='Ranger-like CLI file browser written in Rust'
arch=('i686' 'x86_64')
url='https://github.com/nanoctr/hunter'
license=('custom:WTFPL')
provides=('hunter')
conflicts=('hunter')
depends=('gst-plugins-base-libs' 'libsixel')
makedepends=('rustup'
'git'
'gst-plugins-good'
'gst-plugins-bad'
'gst-plugins-ugly')
optdepends=('gst-plugins-good: Media support'
'gst-plugins-bad: Media support'
'gst-plugins-ugly: Media support'
'gst-libav: Media support'
'nerd-fonts-complete: Icon pack support'
'bat: Syntax highlighting'
'highlight: Syntax highlighting'
'libarchive: Archive support'
'p7zip: Archive support'
'atool: Archive support'
'w3m: HTML support'
'links: HTML support'
'elinks: HTML support'
'lynx: HTML support'
'poppler: PDF support'
'mupdf-tools: PDF support'
'fzf: Default file finder')
source=("hunter::git+${url}.git")
sha256sums=('SKIP')
pkgver() {
cd hunter
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd hunter
rustup override set nightly
cargo build --release
}
package() {
cd hunter
install -D target/release/hunter{,-media} -t "$pkgdir"/usr/bin
install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/hunter
install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/${pkgname}
}
|