PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Jean Lucas <jean@4ray.co>

pkgname=hunter-holy
pkgver=1.3.0
pkgrel=2
pkgdesc='ranger-like file browser written in Rust (holy branch)'
arch=(i686 x86_64)
url=https://github.com/rabite0/hunter
license=(WTFPL)
depends=(xdg-utils gst-plugins-base-libs)
makedepends=(rustup)
optdepends=('gst-plugins-good: media support'
            'gst-plugins-bad: media support'
            'gst-plugins-ugly: media support'
            'gst-libav: media support'
            'nerd-fonts-complete: supported icon pack'
            'bat: syntax highlighting'
            'highlight: syntax highlighting'
            'libarchive: archive support'
            'p7zip: archive support'
            'atool: archive support'
            'w3m: HTML support'
            'links: HTML support'
            'elinks: HTML support'
            'lynx: HTML support'
            'poppler: PDF support'
            'mupdf-tools: PDF support'
            'fzf: default file finder')
provides=(hunter)
conflicts=(hunter)
source=(hunter-holy-$pkgver.tar.gz::$url/archive/v$pkgver-holy.tar.gz)
sha512sums=('81fac08545350eac39a5b7d2b3e258a7d01c75ec8158292200d1505cd459004fa6d30d546b3bc5b5f2ab48d96bb5c7597b2a2a4fc3ac2fade941a283d2af396e')

build() {
  cd hunter-$pkgver-holy
  rustup override set nightly
  cargo build --release
}

package() {
  cd hunter-$pkgver-holy
  install -D target/release/hunter{,-media} -t "$pkgdir"/usr/bin
  install -Dm 644 README.md -t "$pkgdir"/usr/share/doc/hunter
  install -Dm 644 LICENSE -t "$pkgdir"/usr/share/licenses/hunter
}