PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: x70b1
pkgname=('hyprland-plugin-borders-plus-plus' 'hyprland-plugin-csgo-vulkan-fix' 'hyprland-plugin-hyprbars' 'hyprland-plugin-hyprexpo' 'hyprland-plugin-hyprtrails' 'hyprland-plugin-hyprwinwrap')
pkgbase='hyprland-plugins'
pkgver='0.45.1'
pkgrel=1
pkgdesc='Official plugins for Hyprland'
arch=('x86_64')
url='https://github.com/hyprwm/hyprland-plugins'
license=('BSD')
depends=('hyprland=0.45.1')
makedepends=('git' 'hyprland')
source=("$pkgbase::git+https://github.com/hyprwm/hyprland-plugins.git#commit=95fee7d0a7fa48828f5e9da1af6dc1fd7adb360d")
sha256sums=('SKIP')

build() {
    cd "$srcdir/$pkgbase"

    for package in ${pkgname[@]}; do
        plugin=${package##hyprland-plugin-}

        make -C "$plugin" all
    done
}

package_hyprland-plugin-borders-plus-plus() {
    pkgdesc="A Hyprland plugin that adds one or two additional borders to your windows"

    cd "$srcdir/$pkgbase/borders-plus-plus"
    install -Dm755 borders-plus-plus.so "$pkgdir/usr/lib/hyprland-plugins/borders-plus-plus.so"
    install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/hyprland-plugin-borders-plus-plus/LICENSE"
}

package_hyprland-plugin-csgo-vulkan-fix() {
    pkgdesc="A Hyprland plugin that fixes custom resolutions on CS:GO with -vulkan"

    cd "$srcdir/$pkgbase/csgo-vulkan-fix"
    install -Dm755 csgo-vulkan-fix.so "$pkgdir/usr/lib/hyprland-plugins/csgo-vulkan-fix.so"
    install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/hyprland-plugin-csgo-vulkan-fix/LICENSE"
}

package_hyprland-plugin-hyprbars() {
    pkgdesc="A Hyprland plugin that adds simple title bars to windows"

    cd "$srcdir/$pkgbase/hyprbars"
    install -Dm755 hyprbars.so "$pkgdir/usr/lib/hyprland-plugins/hyprbars.so"
    install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/hyprland-plugin-hyprbars/LICENSE"
}

package_hyprland-plugin-hyprexpo() {
    pkgdesc="A Hyprland plugin that adds an expo-like workspace overview"

    cd "$srcdir/$pkgbase/hyprexpo"
    install -Dm755 hyprexpo.so "$pkgdir/usr/lib/hyprland-plugins/hyprexpo.so"
    install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/hyprland-plugin-hyprexpo/LICENSE"
}

package_hyprland-plugin-hyprtrails() {
    pkgdesc="A Hyprland plugin that adds smooth trails behind moving windows"

    cd "$srcdir/$pkgbase/hyprtrails"
    install -Dm755 hyprtrails.so "$pkgdir/usr/lib/hyprland-plugins/hyprtrails.so"
    install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/hyprland-plugin-hyprtrails/LICENSE"
}

package_hyprland-plugin-hyprwinwrap() {
    pkgdesc="A Hyprland clone of xwinwrap that allows you to put any app as a wallpaper"

    cd "$srcdir/$pkgbase/hyprwinwrap"
    install -Dm755 hyprwinwrap.so "$pkgdir/usr/lib/hyprland-plugins/hyprwinwrap.so"
    install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/hyprland-plugin-hyprwinwrap/LICENSE"
}