PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Brandon Clifford <brandon099 at gmail dot com>

_gitname=i3lock-color
pkgname="$_gitname-git"
pkgver=r232.b332ce6
pkgrel=1
pkgdesc="An improved screenlocker based upon XCB and PAM with color configuration support"
arch=('i686' 'x86_64')
url="https://github.com/Arcaena/i3lock-color"
license=('MIT')
depends=('xcb-util-image' 'xcb-util-keysyms' 'pam' 'libev' 'libx11' 'cairo')
provides=('i3lock')
conflicts=('i3lock')
makedepends=('git')
source=("git+https://github.com/Arcaena/$_gitname.git")
md5sums=('SKIP')

pkgver() {
    cd "${srcdir}/${_gitname}"
    echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
    cd "${srcdir}/${_gitname}"
    sed -i 's| -m 644 i3lock-color.1.gz $(MANDIR)| -Dm 644 i3lock-color.1.gz $(DESTDIR)$(MANDIR)|' Makefile
}

build() {
    cd "${srcdir}/${_gitname}"
    make
}

package() {
    cd "${srcdir}/${_gitname}"
    make MANDIR="${pkgdir}/usr/share/man" DESTDIR="$pkgdir" install
    install -Dm644 i3lock-color.1.gz "${pkgdir}/usr/share/man/man1/i3lock-color.1.gz"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${_gitname}/LICENSE"
}