blob: d2a8decdfdc6948e30f962fdd468a04ad8078bf3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: linkfrg
pkgname=ignis-git
_pkgname=ignis
pkgver=0.1.r1.g0ba6573
pkgrel=1
pkgdesc="Full-featured Python framework for building desktop shells using GTK4."
arch=('x86_64')
url="https://github.com/linkfrg/ignis"
license=('GPL-3.0-only')
makedepends=('gobject-introspection' 'meson')
depends=('python' 'glib2' 'glib2-devel' 'glibc' 'gtk4' 'gtk4-layer-shell' 'libpulse' 'python-cairo' 'python-gobject' 'python-click' 'python-requests' 'python-loguru')
optdepends=('gst-plugin-pipewire: required for recorder service'
'gst-plugins-good: required for recorder service'
'gst-plugins-ugly: required for recorder service'
'networkmanager: required for network service'
'dart-sass: SASS/SCSS compilation support')
conflicts=('ignis')
source=("git+${url}"
"git+https://gitlab.gnome.org/GNOME/libgnome-volume-control")
sha256sums=('SKIP'
'SKIP')
pkgver(){
cd $srcdir/$_pkgname
git describe --long --tags --abbrev=7 | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd $srcdir/$_pkgname
git submodule init
git config submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
git -c protocol.file.allow=always submodule update
}
build() {
cd $srcdir/$_pkgname
arch-meson build --libdir "lib/$_pkgname"
meson compile -C build
}
package() {
cd $srcdir/$_pkgname
meson install -C build --destdir "$pkgdir"
}
|