PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer:  Chris Severance aur.severach aATt spamgourmet dott com
# Contributor : mok <mok at ethetricks dot eu>

set -u
pkgname='ike-scan'
pkgver='1.9.5'
pkgrel='1'
pkgdesc='A tool that uses IKE protocol to discover, fingerprint and test IPSec VPN servers'
arch=('i686' 'x86_64')
#url="http://www.nta-monitor.com/tools/${pkgname}/"
url="https://github.com/royhills/${pkgname}/archive/refs/tags"
license=('GPL')
depends=('openssl')
_srcdir="${pkgname}-${pkgver}"
#_verwatch=('http://www.nta-monitor.com/tools-resources/security-tools/ike-scan-archive' ".*${pkgname}-\([0-9\.]\+\)\.tar\.gz" 'l')
#source=("${url}download/${pkgname}-${pkgver}.tar.gz")
#_verwatch=("${url}/releases" "${url#*github.com}/releases/download/.*/${pkgname}-\(.*\)\.tar\.gz" 'l')
source=("${_srcdir}.tar.gz::${url}/${pkgver}.tar.gz")
md5sums=('c72010d37f75642adcc0ec7d001fe1c5')
sha256sums=('5152bf06ac82d0cadffb93a010ffb6bca7efd35ea169ca7539cf2860ce2b263f')

build() {
  set -u
  cd "${_srcdir}"
  if [ ! -s 'configure' ]; then
    autoreconf --install
  fi
  if [ ! -s 'Makefile' ]; then
    ./configure --prefix='/usr' --mandir='/usr/share/man' --with-openssl
  fi
  make -s
  set +u
}

check() {
  set -u
  cd "${_srcdir}"
  make check
  set +u
}

package() {
  set -u
  cd "${_srcdir}"
  make -s DESTDIR="${pkgdir}" install
  set +u
}
set +u