PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Que Quotion <quequotion@bugmenot.com>

pkgname=indicator-sensors-git
pkgver=0.8.r28.gd267b5c
pkgrel=2
pkgdesc="Small application to provide hardware sensor readings using the AppIndicator framework (git version)"
arch=('i686' 'x86_64')
url="https://github.com/alexmurray/indicator-sensors"
license=('GPL3')
provides=('indicator-sensors')
conflicts=('indicator-sensors')
depends=('dconf' 'libappindicator-gtk3' 'libatasmart' 'libnotify' 'libpeas' 'lm_sensors' 'udisks2')
optdepends=('libxnvctrl: NVIDIA GPU support')
makedepends=('gnome-common' 'intltool')
install=indicator-sensors.install
source=("git+https://github.com/alexmurray/indicator-sensors"
        {menu-cleanup,reduce-logging}.patch
        'is-udisks2.rules')
md5sums=('SKIP'
         '7f41886142704131faba29ce87ae07ed'
         '4a1c2fc97d24d4246c7f7e04761a9362'
         '73468b5a1034ed57cb94c48ba26d2300')

pkgver() {
  cd "indicator-sensors"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd indicator-sensors

  #Cleanup indicator menu (remove "about" and "quit")
  patch -Np2 < ../menu-cleanup.patch
  patch -Np2 < ../reduce-logging.patch
}

build() {
  cd indicator-sensors
  sh ./autogen.sh
  ./configure --disable-schemas-compile --prefix=/usr
  make
}

package() {
  cd indicator-sensors
  make DESTDIR="$pkgdir" install
  mkdir -p -m 750 "$pkgdir"/etc/polkit-1/rules.d/
  install -m 644 ../is-udisks2.rules "$pkgdir"/etc/polkit-1/rules.d/
}