PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63

# Maintainer: vscncls <lucaslou4@protonmail.com>

pkgname=insomnia-src
_name=insomnia
pkgver=7.1.1
pkgrel=5
pkgdesc="Cross-platform HTTP and GraphQL Client (Build from source)"
url="https://github.com/Kong/insomnia"
arch=('x86_64' 'i686')
license=('MIT')
depends=('electron4' 'npm')
makedepends=('nodejs-lts-dubnium')
provides=("$_name")
conflicts=("$_name")
source=(
    "${url}/archive/v${pkgver}.tar.gz"
    "${_name}.desktop"
    "${_name}.sh"
)
sha256sums=(
    'eca542e1e5119b1632033c6beae28f924625a0fd3ce21cdbcf1730bc44c6187c'
    '69358bb19108f09b78d97aba7d1813898858be449a13f2d8a6ad03cdce1400a8'
    'fbf24757aeaca7ceab18965774573bff2be540c948a47dd3f95c7b7857ef411c'
)

prepare() {
    cd $_name-$pkgver/packages/insomnia-app
    # Change package.json's electron version
    electronV=$(electron4 --version)
    electronVer=${electronV#v}
    sed -i "/\"electron\": \"/c\\\"electron\": \"$electronVer\"," package.json

    # Edit electron builder config so only the linux-unpacked package is built
    sed -i 's/"AppImage",//' .electronbuilder
    sed -i 's/"deb",//' .electronbuilder
    sed -i 's/"tar.gz",//' .electronbuilder
    sed -i 's/"snap",//' .electronbuilder
    sed -i 's/"rpm"/"dir"/' .electronbuilder

    sed -i "s#\"appId\": \"__APP_ID__\",#\"appId\": \"com.insomnia.app\",#" .electronbuilder
}

build() {
    cd $_name-$pkgver
    npm run bootstrap
    npm run app-package
}

package() {
    # Install asar file
    install -Dm644 $_name-$pkgver/packages/insomnia-app/dist/linux-unpacked/resources/app.asar $pkgdir/usr/share/insomnia/app.asar

    # Install start script
    install -Dm755 $_name.sh $pkgdir/usr/bin/$_name

    install -Dm644 $_name.desktop $pkgdir/usr/share/applications/$_name.desktop

    for size in 16 32 48 128 256 512; do
        install -Dm644 $_name-$pkgver/packages/insomnia-app/build/static/icon.png "$pkgdir/usr/share/icons/hicolor/${size}x${size}/apps/insomnia.png"
    done

    install -Dm644 $_name-$pkgver/LICENSE $pkgdir/usr/share/licenses/$_name/LICENSE
}