blob: 982ea5c2144a3faa6eeae9e091c241b410196142 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer : Daniel Bermond <dbermond@archlinux.org>
# Contributor: Fabio 'Lolix' Loli <fabio.loli@disroot.org>
pkgname=intel-npu-driver
pkgver=1.28.0
pkgrel=1
pkgdesc='Intel Neural Processing Unit (NPU) driver'
arch=('x86_64')
url='https://github.com/intel/linux-npu-driver/'
license=('BSD-3-Clause AND MIT')
depends=(
'gcc-libs'
'glibc'
'gtest'
'level-zero-loader'
'opencv'
'yaml-cpp')
optdepends=('intel-npu-compiler: for compiling OpenVINO IR models')
makedepends=(
'cmake'
'git'
'level-zero-headers'
'libdrm')
install=intel-npu-driver.install
source=("git+https://github.com/intel/linux-npu-driver.git#tag=v${pkgver}"
'git+https://github.com/intel/level-zero-vpu-extensions.git'
'git+https://github.com/openvinotoolkit/npu_compiler_elf.git'
'git+https://github.com/google/perfetto.git'
'10-intel-npu.rules'
'010-intel-npu-driver-rename-installed-binaries.patch'
'020-intel-npu-driver-disable-gtest-and-yaml.patch'
'030-intel-npu-driver-fix-firmware-install-path.patch'
'040-intel-npu-driver-use-system-level-zero.patch')
sha256sums=('741ed482b02efae4e86f958c3eac56ebcb7f197d273e39dcd391d8974d48286b'
'SKIP'
'SKIP'
'SKIP'
'592a2f5575ecce93a03c66987573fe675d41a63b49cee11d2553645d9e5624fe'
'97dbb45e871d108a7996428963dda81546b8c26e698d54f4743b878ef9ea3408'
'861c3872934357048746d308732dd28b880c442702470d0191c9fc01a2aab1b8'
'c378987c3da52988402d93f396d4084c86c2ddce9c0e2af3284631e6f1796825'
'a257456a61d5ec670c26b2c6d23f23f03b68ff6e64f74539c17b2c7e1b074f25')
prepare() {
git -C linux-npu-driver submodule init
git -C linux-npu-driver config --local submodule.third_party/level-zero.update none
git -C linux-npu-driver config --local submodule.third_party/level-zero-vpu-extensions.url "${srcdir}/level-zero-vpu-extensions"
git -C linux-npu-driver config --local submodule.third_party/npu_compiler_elf.url "${srcdir}/npu_compiler_elf"
git -C linux-npu-driver config --local submodule.third_party/googletest.update none
git -C linux-npu-driver config --local submodule.third_party/yaml-cpp.update none
git -C linux-npu-driver config --local submodule.third_party/perfetto.url "${srcdir}/perfetto"
git -C linux-npu-driver -c protocol.file.allow='always' submodule update
patch -d linux-npu-driver -Np1 -i "${srcdir}/010-intel-npu-driver-rename-installed-binaries.patch"
patch -d linux-npu-driver -Np1 -i "${srcdir}/020-intel-npu-driver-disable-gtest-and-yaml.patch"
patch -d linux-npu-driver -Np1 -i "${srcdir}/030-intel-npu-driver-fix-firmware-install-path.patch"
patch -d linux-npu-driver/third_party/level-zero-npu-extensions -Np1 -i "${srcdir}/040-intel-npu-driver-use-system-level-zero.patch"
}
build() {
# fix error: "_FORTIFY_SOURCE" redefined
# note: upstream forces _FORTIFY_SOURCE=2
export CFLAGS="${CFLAGS/-Wp,-D_FORTIFY_SOURCE=?/}"
export CXXFLAGS="${CXXFLAGS/-Wp,-D_FORTIFY_SOURCE=?/}"
cmake -B build -S linux-npu-driver \
-G 'Unix Makefiles' \
-DCMAKE_BUILD_TYPE:STRING='None' \
-DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-DENABLE_NPU_COMPILER_BUILD:BOOL='OFF' \
-DENABLE_SANITIZER:STRING='disabled' \
-Wno-dev
cmake --build build
}
package() {
DESTDIR="$pkgdir" cmake --install build
chmod 644 "${pkgdir}/usr/lib/firmware/updates/intel/vpu"/vpu_*.bin
install -D -m644 10-intel-npu.rules -t "${pkgdir}/usr/lib/udev/rules.d"
install -D linux-npu-driver/LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -D linux-npu-driver/firmware/bin/COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE-firmware"
}
|