blob: 372fc47bc5189b4ca4bab90eb22aed5fd7842d63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Urs Wolfer <uwolfer @ fwo.ch>
pkgbase=intellij-idea-ultimate-edition
pkgname=(intellij-idea-ultimate-edition intellij-idea-ultimate-edition-jre)
pkgver=2019.1.3
_buildver=191.7479.19
pkgrel=1
arch=('any')
pkgdesc="An intelligent IDE for Java, Groovy and other programming languages with advanced refactoring features intensely focused on developer productivity."
url="https://www.jetbrains.com/idea/"
license=('Commercial')
options=(!strip)
source=("https://download.jetbrains.com/idea/ideaIU-$pkgver.tar.gz"
"jetbrains-idea.desktop")
sha256sums=('e3c19c6ebd99bd78c5e7b14c58362ddb441ad31d56d477ac719e89d367f9e14d'
'83af2ba8f9f14275a6684e79d6d4bd9b48cd852c047dacfc81324588fa2ff92b')
prepare() {
# Extract the JRE from the main pacakge
mv idea-IU-$_buildver/jre64 "$srcdir"/jre64
}
package_intellij-idea-ultimate-edition() {
backup=("opt/$pkgname/bin/idea.vmoptions" "opt/${pkgname}/bin/idea64.vmoptions" "opt/${pkgname}/bin/idea.properties")
depends=('giflib' 'libxtst')
optdepends=(
'intellij-idea-ultimate-edition-jre: JetBrains custom JRE (Recommended)' 'java-environment: Required if intellij-idea-ultimate-edition-jre is not installed'
'libdbusmenu-glib: For global menu support'
)
cd "$srcdir"
install -d "$pkgdir"/{opt/$pkgname,usr/bin}
mv idea-IU-${_buildver}/* "$pkgdir"/opt/$pkgbase
# https://youtrack.jetbrains.com/issue/IDEA-185828
chmod +x "$pkgdir"/opt/$pkgbase/plugins/maven/lib/maven3/bin/mvn
ln -s /opt/$pkgname/bin/idea.sh "$pkgdir"/usr/bin/$pkgname
install -D -m644 "$srcdir"/jetbrains-idea.desktop "$pkgdir"/usr/share/applications/jetbrains-idea.desktop
install -D -m644 "$pkgdir"/opt/$pkgbase/bin/idea.png "$pkgdir"/usr/share/pixmaps/"$pkgname".png
# workaround FS#40934
sed -i 's|lcd|on|' "$pkgdir"/opt/$pkgname/bin/*.vmoptions
}
package_intellij-idea-ultimate-edition-jre() {
arch=('x86_64')
install -d -m 755 "$pkgdir"/opt/$pkgbase
mv "$srcdir"/jre64 "$pkgdir"/opt/$pkgbase
}
# vim:set ts=2 sw=2 et:
|