PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer : Daniel Bermond <dbermond@archlinux.org>

pkgname=irpf2022
pkgver=2022.1.9
pkgrel=1
pkgdesc='Brazilian physical person income tax (IRPF) program (2022 version)'
arch=('any')
url='https://www.gov.br/receitafederal/pt-br/assuntos/meu-imposto-de-renda'
license=('custom')
depends=('sh' 'java-runtime=11' 'hicolor-icon-theme')
makedepends=('imagemagick' 'librsvg')
source=("https://downloadirpf.receita.fazenda.gov.br/irpf/${pkgver%%.*}/irpf/arquivos/IRPF${pkgver%%.*}-${pkgver#*.}.zip"
        'https://upload.wikimedia.org/wikipedia/commons/e/e8/Logo_Receita_Federal_do_Brasil.svg'
        'irpf.desktop'
        'irpf.sh'
        'LICENSE')
sha256sums=('be419e51a833112eca3b3c67cacdeaa3cc18e0026a18596a1dc197b00e9c8ede'
            '60c46521699aa3aeaadcb6a51b2727f3e9eb0c23a99334903c01f858c16f8f73'
            '1ecd7bda136768becefc2dbb7da7a1de3471f193b0242a2acf6413a3f5d04e8b'
            '02ddb198b6fae53f437af2a13a1de8088d7990aa3b94cac368ac95de2b4796fe'
            'a406e102e2c10c202bd7a0ba775b004c0f04440544db73ce6923172a62aacd67')

prepare() {
	local _res
	for _res in 16 32 48 64 128 256
	do
		magick -background none Logo_Receita_Federal_do_Brasil.svg -resize "${_res}x${_res}" "IRPF${pkgver%%.*}/irpf_${_res}x${_res}.png"
	done
}

package() {
	install -D -m755 irpf.sh "${pkgdir}/usr/bin/irpf-${pkgver%%.*}"
	install -D -m644 irpf.desktop "${pkgdir}/usr/share/applications/irpf-${pkgver%%.*}.desktop"
	install -D -m644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
	install -D -m644 "IRPF${pkgver%%.*}"/{irpf,pgd-updater}.jar -t "${pkgdir}/usr/share/java/irpf-${pkgver%%.*}"
	install -D -m644 "IRPF${pkgver%%.*}/Leia-me.htm" -t "${pkgdir}/usr/share/doc/irpf-${pkgver%%.*}"
	cp -dr --no-preserve='ownership' "IRPF${pkgver%%.*}/help" "${pkgdir}/usr/share/doc/irpf-${pkgver%%.*}"
	cp -dr --no-preserve='ownership' "IRPF${pkgver%%.*}/"lib{,-modulos} "${pkgdir}/usr/share/java/irpf-${pkgver%%.*}"
	ln -s "../../doc/irpf-${pkgver%%.*}/help" "${pkgdir}/usr/share/java/irpf-${pkgver%%.*}/help"
	
	local _res
	for _res in 16 32 48 64 128 256
	do
		install -D -m644 "IRPF${pkgver%%.*}/irpf_${_res}x${_res}.png" "${pkgdir}/usr/share/icons/hicolor/${_res}x${_res}/apps/irpf-${pkgver%%.*}.png"
	done
}