blob: ea8f7faa58bdea6b015b161edf233640abd783a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=jamesdsp-pulse
_app_id=me.timschneeberger.jdsp4linux.pulse
pkgver=2.7.0
pkgrel=3
pkgdesc="An audio effect processor for PulseAudio clients"
arch=('x86_64')
url="https://github.com/Audio4Linux/JDSP4Linux"
license=('GPL-3.0-or-later')
depends=('glibmm' 'gst-plugins-good' 'hicolor-icon-theme' 'libarchive' 'libpulse'
'qt6-svg')
makedepends=('git')
provides=('jamesdsp')
conflicts=('jamesdsp' 'jdsp4linux' 'jdsp4linux-gui' 'gst-plugin-jamesdsp')
options=('!strip')
_commit=30a30aa5ce90f97ea2c93bc372c0a67c8e3c54c8 # tags/2.7.0^0
source=("git+https://github.com/Audio4Linux/JDSP4Linux.git#commit=$_commit"
'git+https://github.com/ThePBone/GraphicEQWidget.git'
'git+https://github.com/ThePBone/FlatTabWidget.git'
'git+https://github.com/ThePBone/LiquidEqualizerWidget.git'
'git+https://github.com/ThePBone/LiveprogIDE.git')
sha256sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd JDSP4Linux
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd JDSP4Linux
git submodule init
for submodule in GraphicEQWidget FlatTabWidget LiquidEqualizerWidget LiveprogIDE; do
git config submodule.src/subprojects/"${submodule}".url "$srcdir/${submodule}"
done
git -c protocol.file.allow=always submodule update
mkdir -p build
}
build() {
cd JDSP4Linux
pushd build
qmake6 .. "CONFIG += USE_PULSEAUDIO"
make
strip --strip-unneeded src/jamesdsp
popd
}
package() {
cd JDSP4Linux
install -Dm755 build/src/jamesdsp -t "$pkgdir/usr/bin/"
install -Dm644 resources/icons/icon.png \
"$pkgdir/usr/share/pixmaps/${_app_id}.png"
install -Dm644 resources/icons/icon.svg \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/${_app_id}.svg"
install -Dm644 "meta/flatpak/${_app_id}.desktop" -t \
"$pkgdir/usr/share/applications/"
install -Dm644 "meta/flatpak/${_app_id}.metainfo.xml" -t \
"$pkgdir/usr/share/metainfo/"
}
|