blob: 952b16bd1866ca0675ea86e64933300a7d52ea4f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: GrayJack <gr41.j4ck@gmail.com>
# Contributor: Thomas Jost <schnouki@schnouki.net>
_pkgname=janet
pkgname=janet-lang
pkgver=1.32.1
_jpm_commit=cebf7c1
pkgrel=1
pkgdesc="A dynamic Lisp dialect and bytecode vm"
arch=('arm' 'armv6h' 'armv7h' 'i686' 'x86_64' 'aarch64')
url="https://janet-lang.org/"
license=('MIT')
depends=('glibc')
makedepends=('git')
provides=('janet' 'jpm')
conflicts=('janet-lang-git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/janet-lang/janet/archive/v${pkgver}.tar.gz"
"git+https://github.com/janet-lang/jpm#commit=${_jpm_commit}"
"default-config.janet")
sha256sums=('ac74444f1b545830c34738fe9ebb58c865ea4b819b0b0c3124315c646d9ce4cb'
'SKIP'
'7fb56585e6027ea800920a364acd73b49205298dcf887a4ee71fb65125c4539f')
options=('staticlibs')
build() {
cd "${srcdir}"/$_pkgname-$pkgver
CFLAGS+=" -fPIC"
LDFLAGS+=" -rdynamic"
make PREFIX="/usr" all build/janet.pc docs
}
package() {
cd "${srcdir}"/$_pkgname-$pkgver
make DESTDIR="${pkgdir}" PREFIX=/usr install
install -dm755 "${pkgdir}"/usr/share/janet
cp -a examples "${pkgdir}"/usr/share/janet
install -Dm644 build/doc.html "${pkgdir}"/usr/share/doc/janet/doc.html
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
cd "${srcdir}"/jpm
install -Dm755 -t "${pkgdir}"/usr/bin jpm/jpm
install -Dm644 -t "${pkgdir}"/usr/lib/janet/jpm jpm/*.janet
install -Dm644 -t "${pkgdir}"/usr/share/man/man1 jpm.1
install -Dm644 -t "${pkgdir}"/usr/share/janet/jpm/configs configs/*
install -Dm644 -t "${pkgdir}"/usr/lib/janet/jpm "${srcdir}"/default-config.janet
}
|