blob: d3da45c94919a1535893f7399afb2d8d89ed5595 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Guillaume ALAUX <guillaume@archlinux.org>
_libname=jdepend
pkgname=java-${_libname}
pkgver=2.9.1
pkgrel=4
pkgdesc="Java library for generating design quality metrics"
arch=('any')
url="https://github.com/clarkware/jdepend"
license=('BSD')
depends=('java-runtime-headless')
makedepends=('apache-ant')
checkdepends=('apache-ant')
source=($pkgname-$pkgver.tar.gz::https://github.com/clarkware/jdepend/archive/${pkgver}.tar.gz)
sha512sums=('05dd4451c3da38469ef65051862d3299a6beac373605b7a65300e3322d32907702c2925bf7225716e6ce8b56b55c159fd673632f47961b0e2e13a2788b5b2d17')
build() {
cd ${_libname}-${pkgver}
ant jar
}
check() {
cd ${_libname}-${pkgver}
ant test
}
package() {
cd ${_libname}-${pkgver}
install -Dm644 dist/${_libname}-${pkgver}.jar "${pkgdir}"/usr/share/java/${_libname}-${pkgver}.jar
ln -s ${_libname}-${pkgver}.jar "${pkgdir}"/usr/share/java/${_libname}.jar
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|