PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: PureFallen <archlinux.snoring858@passmail.net>
# Contributor: Godeps <Godeps@protonmail.com>
# Previously based on nns's jdk17-graalvm-ee-bin AUR package

_majorver=11
_jvmdir=/usr/lib/jvm/java-${_majorver}-graalvm-ee/
pkgname="jdk${_majorver}-graalvm-ee-bin"
pkgver=21.3.17
pkgrel=1
epoch=1
pkgdesc="Universal virtual machine for running applications written in a variety of languages (JVM-based, LLVM-based, or other), Java ${_majorver} version"
arch=('x86_64'
      'aarch64')
url='https://www.graalvm.org/'
license=('custom:OTN')
depends=('java-runtime-common'
	 'java-environment-common'
         'ca-certificates-utils')
makedepends=()
optdepends=("graal-nodejs-jdk${_majorver}-bin: Node.js component (used to be bundled with this package before the 21.1.0 release)")
provides=("java-runtime=${_majorver}"
	  "java-runtime-headless=${_majorver}"
	  "java-environment=${_majorver}")
options=('staticlibs'
	 '!debug')
install="$pkgname.install"
source=('graalvm-ee-rebuild-libpolyglot.hook')
sha256sums=('7dc37bd3703ebebcd6efa39534e6bb6e3ec9c8ee0d97e46d6df5349739c7d2ca')
# tarball must be manually downloaded from https://www.oracle.com/downloads/graalvm-downloads.html
source_x86_64=("local://graalvm-ee-java${_majorver}-linux-amd64-${pkgver}.tar.gz")
sha256sums_x86_64=('2d4a3cd5800806c300a201e8d55b34727a2907ba01686418efff6d393c2e8815')
source_aarch64=("local://graalvm-ee-java${_majorver}-linux-aarch64-${pkgver}.tar.gz")
sha256sums_aarch64=('9c98b94558c5c98f7123de298ec83a9ffeed0eec251873345d8c9b37426973bf')

package() {
	# Grab all contents of tarball and extract to correct places
	install -dm 755 "${pkgdir}${_jvmdir}"
	cp -ar "${srcdir}/graalvm-ee-java${_majorver}-${pkgver}/." "${pkgdir}${_jvmdir}"

	# License
	cd "${srcdir}/graalvm-ee-java${_majorver}-${pkgver}"
	install -DTm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

	# Man pages
	cd "${pkgdir}${_jvmdir}"
	for f in man/man1/*; do
		install -DTm644 "${f}" "${pkgdir}/usr/share/${f/\.1/-graalvm-ee-java${_majorver}.1}"
	done

	# Polyglot hook
	cd "${srcdir}"
	sed "s/JAVA/${_majorver}/g" < "graalvm-ee-rebuild-libpolyglot.hook" > "graalvm-ee-jdk${_majorver}-rebuild-libpolyglot.hook"
	install -DTm644 "graalvm-ee-jdk${_majorver}-rebuild-libpolyglot.hook" "${pkgdir}/usr/share/libalpm/hooks/graalvm-ee-jdk${_majorver}-rebuild-libpolyglot.hook"
}