blob: 011deb6a7a55a859d772c71e304102746f571d25 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=jjj
pkgver=0.2.1
pkgrel=1
pkgdesc="A modal interface for Jujutsu"
arch=('x86_64')
url="https://github.com/icorbrey/jjj"
license=('MIT')
depends=('gcc-libs')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('012d111279821ca9c34bdb5d2562f3241cd9cac83f1239e33fd59ded3f2daff3')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --frozen
}
check() {
cd "$pkgname-$pkgver"
cargo test --frozen
}
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname"
}
|