blob: 8e9535fdde41db46da4a4458f0821f8e58f3aad0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Carl Smedstad <carsme@archlinux.org>
pkgname=jnv
pkgver=0.2.2
pkgrel=1
pkgdesc="Interactive JSON filter using jq"
arch=(x86_64)
url="https://github.com/ynqa/jnv"
license=(MIT)
depends=(
gcc-libs
glibc
)
makedepends=(
cargo
clang
)
options=(!lto)
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('10304d81f31056a456c00e638ea80ca6506d414b56bb87c8294394de7d31edfb')
_archive="$pkgname-$pkgver"
prepare() {
cd "$_archive"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$_archive"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "$_archive"
export RUSTUP_TOOLCHAIN=stable
cargo test --frozen --all-features
}
package() {
cd "$_archive"
install -Dm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|