PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>

pkgname=joymap
pkgver=0.5.9
pkgrel=2
pkgdesc='A linux userspace device driver that allows joystick events to be remapped.'
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/linuxjoymap'
license=('GPL-2.0-only')
depends=()
makedepends=()
source=(
	"$pkgname-$pkgver.tar.gz::${url}/files/$pkgname-${pkgver}.tar.gz/download"
	'joymap-user.service'
	'joymap-system.service'
	'joymap-sysuser.conf'
	'90-joymap-uinput.rules')
sha256sums=('a4c178eae4693e51c114b2a1f462bde33b822edb31de2495693be2940b0fd1e7'
            '427aae12107225ed8e47a2c9ec77539723cce98f340316a08d9d68b0514b78ec'
            '645d3cce9d9d196428348e638841626a8df83b0fad90c0c6bcae39e4de87010a'
            '1bbbbe0f795adcb11f7284d17b0e67dc6c3d8577f4509f83e64936d99e504fc7'
            '61068aaf6e67b8739acbdc93f44353f4666a00bfd3fae8b50c952a97b7a35ac6')
install='joymap.install'

_srcdir="$pkgname-${pkgver}"

build() {
	cd "${_srcdir}"
	make
}

package() {
	install -Dm644 'joymap-user.service' "${pkgdir}/usr/lib/systemd/user/joymap.service"
	install -Dm644 'joymap-system.service' "${pkgdir}/usr/lib/systemd/system/joymap.service"
	install -Dm644 'joymap-sysuser.conf' "${pkgdir}/usr/lib/sysusers.d/joymap.conf"
	install -Dm644 '90-joymap-uinput.rules' -t "${pkgdir}/usr/lib/udev/rules.d"

	cd "${_srcdir}"
	install -Dm755 'loadmap' "${pkgdir}/usr/bin/joymap"
	install -Dm755 'reserve_js' "${pkgdir}/usr/bin/joymap-reserve_js"
	install -Dm755 'joymap_blocker.so' -t "${pkgdir}/usr/lib"
}