PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Maintainer: XOX (milklikecomputer) <0c2c5a81-0f19-4c94-bf0b-a693e3ced027[at]slmails[dot]me>

pkgname='jre-zulu-bin'
pkgver='23.0.1'
pkgrel=1
pkgdesc='A open source, TCK-tested and certified builds of OpenJDK (full-runtime environment).'
arch=('aarch64' 'x86_64')
url='https://www.azul.com/'
license=('LicenseRef-Java')
depends=(
  'java-environment-common>=3'
  'java-runtime-common>=3'
  'ca-certificates-utils'
)
provides=(
  'java-environment=23'
  'java-environment-openjdk=23'
  'java-runtime=23'
  'java-runtime-openjdk=23'
  'java-runtime-headless=23'
  'java-runtime-headless-openjdk=23'
)
conflicts=('jre-zulu-fx-bin' 'zulu-23-bin' 'zulu-fx-bin')
install="install_${pkgname}.install"
source_aarch64=('https://cdn.azul.com/zulu/bin/zulu23.30.13-ca-jre23.0.1-linux_aarch64.tar.gz')
source_x86_64=('https://cdn.azul.com/zulu/bin/zulu23.30.13-ca-jre23.0.1-linux_x64.tar.gz')
sha256sums_aarch64=('d74cd3f6b2152c675f7eee51c59c6b3c8e81951e8d46aaae0fa9550b6cce3d00')
sha256sums_x86_64=('7e0d7f638d6c3453b390953be5376221e73efda83d72c3cfac346a4c1469dc10')

_jvmdir='/usr/lib/jvm/java-23-zulujdk'

package() {
  if [ "${CARCH}" = "aarch64" ]; then
    cd "$srcdir/zulu23.30.13-ca-jre${pkgver}-linux_aarch64"
  else
    cd "$srcdir/zulu23.30.13-ca-jre${pkgver}-linux_x64"
  fi

  install -dm 755 "${pkgdir}/${_jvmdir}"
  cp -a . "${pkgdir}/${_jvmdir}/"

  # based on java-openjdk (package_jre-openjdk, jdk-openjdk), zulu-23-bin and zulu-fx-bin

  # Conf
  install -dm 755 "${pkgdir}/etc"
  cp -r conf "${pkgdir}/etc/${pkgname}"
  rm -r "${pkgdir}/${_jvmdir}/conf"
  ln -s "/etc/${pkgname}" "${pkgdir}/${_jvmdir}/conf"

  # Legal
  install -dm 755 "${pkgdir}/usr/share/licenses"
  cp -r legal "${pkgdir}/usr/share/licenses/${pkgname}"
  rm -r "${pkgdir}/${_jvmdir}/legal"
  ln -s "/usr/share/licenses/${pkgname}" "${pkgdir}/${_jvmdir}/legal"

  # Link JKS keystore from ca-certificates-utils
  rm -f "${pkgdir}/${_jvmdir}/lib/security/cacerts"
  ln -sf /etc/ssl/certs/java/cacerts "${pkgdir}/${_jvmdir}/lib/security/cacerts"
}