PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Michael J. Pento <mjpento@verizon.net>
# Maintainer: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>
# https://github.com/zizzfizzix/pkgbuilds

##############################################################
#### The section below can be adjusted to suit your needs ####
##############################################################

# What type of build do you want?
# See http://techbase.kde.org/Development/CMake/Addons_for_KDE#Buildtypes to check what is supported.

_buildtype='RelWithDebInfo'

##############################################################

pkgname=jreen-git
pkgver=1.3.0.r2.gc04c229
pkgrel=1
epoch=1
pkgdesc='Free and Opensource Jabber library, written in C++ using cross-platform framework Qt. - development version'
arch=('i686' 'x86_64')
url='https://github.com/euroelessar/jreen'
license=('GPL2')
depends=('gsasl' 'qt4' 'speex')
makedepends=('git' 'cmake')
provides=('jreen')
conflicts=('jreen')
source=("${pkgname}::git+https://github.com/euroelessar/jreen.git")
md5sums=('SKIP')

if [[ ! ${_buildtype} == 'Release' ]] && [[ ! ${_buildtype} == 'release' ]]; then
  options=('debug')
fi

pkgver() {
  cd "${srcdir}/${pkgname}"
  git describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./g'
}

build() {
  cd "${srcdir}/${pkgname}"

  cmake -DJREEN_FORCE_QT4=on \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=${_buildtype}
  make
}

package() {
  cd "${srcdir}/${pkgname}"
  make DESTDIR="${pkgdir}" install
}