blob: 7e14beb5f26d458fc62fcad2cf7618e01921fb1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# vim: expandtab shiftwidth=2 tabstop=2 softtabstop=4
# Maintainer: Peter Cai <peter@typeblog.net>
pkgname=juicefs-oss
_pkgname=juicefs
pkgver=1.2.0dev
_pkgver=$(echo $pkgver | sed -E 's/^([0-9\.]+)([^0-9].*)?$/\1-\2/' | sed -E 's/-$//')
pkgrel=1
pkgdesc="A distributed POSIX file system built on top of Redis and S3. (FOSS version)"
arch=('x86_64')
url="https://github.com/juicedata/juicefs"
license=('AGPL3')
conflicts=('juicefs')
depends=('glibc')
makedepends=('go')
source=("juicefs-$_pkgver.tar.gz::https://github.com/juicedata/juicefs/archive/refs/tags/v$_pkgver.tar.gz")
sha256sums=('ace6b0e0b3c6cd16bd16fbec3da595ea3062ca619b58d13aafb63fbf48407515')
prepare() {
cd "$_pkgname-$_pkgver"
mkdir -p build/
}
build() {
cd "$_pkgname-$_pkgver"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
go build -o build/$_pkgname .
}
package() {
cd "$_pkgname-$_pkgver"
install -Dm755 build/$_pkgname "$pkgdir"/usr/bin/$_pkgname
ln -s /usr/bin/$_pkgname "$pkgdir"/usr/bin/mount.$_pkgname
}
|