PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: Jakub Klinkovský <lahwaacz at archlinux dot org>
# Maintainer: Specter119 <spcter119 AT gmail.com>

pkgname=jupyter-lsp
pkgver=2.2.5
pkgrel=2
pkgdesc="Multi-Language Server WebSocket proxy for Jupyter Notebook/Lab server."
arch=(any)
url="https://github.com/jupyter-lsp/jupyterlab-lsp"
license=(BSD-3-Clause)
depends=(python jupyter-server)
makedepends=(python-build python-installer python-wheel python-setuptools)
optdepends=(
  bash-language-server
  javascript-typescript-langserver
  jedi-language-server
  python-lsp-server
  pyright
  r-languageserver
  texlab
  sql-language-server
  vscode-css-languageserver
  vscode-json-languageserver
  yaml-language-server)
source=("$url/archive/refs/tags/$pkgname-$pkgver.tar.gz")
sha256sums=('22ecda5d95ea6d0f1f313c24c0ef78f255bc53826ebeb9706f39660414b74f20')

build() {
  cd jupyterlab-lsp-$pkgname-$pkgver/python_packages/jupyter_lsp
  python -m build --wheel --no-isolation
}

package() {
  cd jupyterlab-lsp-$pkgname-$pkgver/python_packages/jupyter_lsp
  python -m installer --destdir=$pkgdir dist/*.whl
  mv $pkgdir/{usr,}/etc
  install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}